graphical-interface.idl

Go to the documentation of this file.

// file graphicalinterface.idl
module gepetto {
  exception Error
  {
    string msg;
  };

module corbaserver {

// Comments :
// 1)  Node names are parsed, so if you call a node "node1/xxx", this node will
//     be automatically added as a child of node1
// 2)  Functions return False if an error occured (in that case, check the
//     SceneViewer-corbaserver window for more information)
// 3)  applyConfiguration doesn't move object straigh forward, you need to used
//     the "refresh" function each time you want actualize position of the Viewer.
//     This system is used to synchronize movement of all objects.

typedef float Transform [7];
typedef float Vector2 [2];
typedef float Position [3];
typedef float Color [4];
typedef string WindowID;
typedef sequence <string> Names_t; 
typedef sequence<float> floatSeq;
typedef sequence<Position> PositionSeq;
typedef sequence<Color> ColorSeq;
typedef sequence<Transform> TransformSeq;

  interface NodeCallback {
    void selected (in string name, in Position positionInWorldFrame, in Position normalInLocalFrame) raises (Error);
  };

  interface GraphicalInterface {


    WindowID createWindow(in string name) raises (Error);

    WindowID getWindowID (in string name) raises (Error);
    
    boolean setBackgroundColor1(in WindowID wid,in Color RGBAcolor);
    
    boolean setBackgroundColor2(in WindowID wid,in Color RGBAcolor);

    void createScene(in string sceneName) raises (Error);

    void createSceneWithFloor(in string sceneName) raises (Error);

    boolean addSceneToWindow(in string sceneName, in WindowID wid) raises (Error);



    boolean addFloor(in string floorName) raises (Error);

    boolean addBox(in string boxName, in float boxSize1, in float boxSize2, in float boxSize3, in Color RGBAcolor) raises (Error);

    boolean addCapsule(in string name, in float radius, in float height, in Color RGBAcolor) raises (Error);


    boolean addArrow(in string name, in float radius, in float length, in Color RGBAcolor) raises (Error);

    boolean addRod(in string rodName, in Color RGBAcolor, in float radius, in float totalLength,in short maxCapsule) raises (Error);
    
    boolean resizeCapsule(in string capsuleName,in float height) raises (Error);

    boolean resizeArrow(in string capsuleName,in float radius, in float length) raises (Error);

    boolean addMesh(in string meshName, in string meshPath) raises (Error);

    void removeLightSources(in string meshName) raises (Error);

    boolean addCone(in string name, in float radius, in float height, in Color RGBAcolor) raises (Error);

    boolean addCylinder(in string cylinderName, in float radius, in float height, in Color RGBAcolor) raises (Error);

    boolean addSphere(in string sphereName, in float radius, in Color RGBAcolor) raises (Error);

    boolean addLight(in string lightName, in WindowID wid, in float radius, in Color RGBAcolor) raises (Error);

    boolean addLine(in string lineName, in Position pos1, in Position pos2, in Color RGBAcolor) raises (Error);
    
    boolean setLineStartPoint(in string lineName, in Position pos1) raises (Error);

    boolean setLineEndPoint(in string lineName, in Position pos2) raises (Error);
    
    boolean setLineExtremalPoints(in string lineName, in Position pos1, in Position pos2) raises (Error);
    
    boolean addCurve(in string name, in PositionSeq pos, in Color RGBAcolor) raises (Error);
    
    boolean setCurvePoints(in string name, in PositionSeq pos) raises (Error);

    boolean setCurveColors(in string name, in ColorSeq pos) raises (Error);

    boolean setCurveMode (in string name, in string mode) raises (Error);

    boolean setCurvePointsSubset (in string curveName, in long first, in long count) raises (Error);

    boolean setCurveLineWidth (in string curveName, in float width) raises (Error);

    boolean addSquareFace(in string faceName, in Position pos1, in Position pos2, in Position pos3, in Position pos4, in Color RGBAcolor) raises (Error);

    boolean setTexture (in string nodeName, in string filename) raises (Error);

    boolean addTriangleFace(in string faceName, in Position pos1, in Position pos2, in Position pos3, in Color RGBAcolor) raises (Error);


    // Add a sphere with xyz axis
    // The colors are x=red, y=green, z=blue (xyz=RGB)
    // \param nodeName : name of the node
    // \param RGBAcolor : color of the sphere
    // \param radius : radius of the sphere
    // \param sizeAxis : size of the axis
    boolean addXYZaxis(in string nodeName, in Color RGBAcolor,in float radius,in float sizeAxis) raises(Error);

        // Add an empty roadmap to the scene
      // \param nameCorba : name of the roadmap
      // \param RGBAcolorNode : color of the sphere
      // \param radius : radius of the sphere
      // \param sizeAxis :size of the axis (proportionnaly to the sphere radius, size axis = 1 -> axis are radius*4 in length and radius/4 in radius)
      // \param RGBAcolorEdge : color of the edges
    boolean createRoadmap(in string nameCorba,in Color RGBAcolorNode, in float radius, in float sizeAxis, in Color RGBAcolorEdge) raises(Error);

        // Add an edge to the roadmap
      // \param nameRoadmap : name of the roadmap
      // \param posFrom : position of the beginning of the edge
      // \param posTo : position of the end of the edge (not oriented edge, order doesn't matter)
    boolean addEdgeToRoadmap(in string nameRoadmap, in Position posFrom, in Position posTo)raises(Error);

        // Add a node to the roadmap
      // \param nameRoadmap : name of the roadmap
      // \param configuration : configuration of the node 
    boolean addNodeToRoadmap(in string nameRoadmap, in Transform configuration)raises(Error);

    boolean addURDF (in string robotName, in string urdfFilePath)
      raises (Error);

    boolean addUrdfCollision (in string robotName, in string urdfFilePath)
      raises (Error);

    void addUrdfObjects (in string nodeName, in string urdfFilePath,
                         in boolean visual)
      raises (Error);

    boolean createGroup(in string groupName) raises (Error);



    boolean nodeExists(in string nodeName) raises (Error);

    void deleteNode (in string nodeName, in boolean all) raises (Error);

    Names_t getNodeList() raises (Error);

    Names_t getGroupNodeList(in string group) raises (Error);

    Names_t getSceneList() raises (Error);

    Names_t getWindowList() raises (Error);

    boolean addToGroup(in string nodeName, in string groupName) raises (Error);

    boolean removeFromGroup(in string nodeName, in string groupName) raises (Error);



    boolean applyConfiguration(in string nodeName, in Transform configuration) raises (Error);

    boolean applyConfigurations(in Names_t nodeName, in TransformSeq configuration) raises (Error);

    void refresh() raises (Error);

    void setRefreshIsSynchronous (in boolean synchonous) raises (Error);
    
    Transform getNodeGlobalTransform(in string nodeName) raises (Error);



    boolean addLandmark(in string nodeName, in float size) raises (Error);

    boolean deleteLandmark(in string nodeName) raises (Error);

    Transform getStaticTransform(in string nodeName) raises (Error);
    
    boolean setStaticTransform(in string nodeName, in Transform configuration) raises (Error);

    boolean setVisibility(in string nodeName, in string visibilityMode) raises (Error);
    
    boolean setScale(in string nodeName, in Position scale) raises (Error);
    
    boolean setColor(in string nodeName, in Color scale) raises (Error);

    boolean setWireFrameMode(in string nodeName, in string wireFrameMode) raises (Error);

    boolean setLightingMode(in string nodeName, in string lightingMode) raises (Error);

    boolean setHighlight (in string nodeName, in long state) raises (Error);

    Names_t getPropertyNames(in string nodeName) raises (Error);
    Names_t getPropertyTypes(in string nodeName) raises (Error);

    void setStringProperty(in string nodeName, in string propName, in string value) raises (Error);
    string getStringProperty(in string nodeName, in string propName) raises (Error);

    void setColorProperty(in string nodeName, in string propName, in Color value) raises (Error);
    Color getColorProperty(in string nodeName, in string propName) raises (Error);

    void setVector3Property(in string nodeName, in string propName, in Position value) raises (Error);
    Position getVector3Property(in string nodeName, in string propName) raises (Error);

    void setVector2Property(in string nodeName, in string propName, in Vector2 value) raises (Error);
    Position getVector2Property(in string nodeName, in string propName) raises (Error);

    void setFloatProperty(in string nodeName, in string propName, in float value) raises (Error);
    float getFloatProperty(in string nodeName, in string propName) raises (Error);

    void setBoolProperty(in string nodeName, in string propName, in boolean value) raises (Error);
    boolean getBoolProperty(in string nodeName, in string propName) raises (Error);

    void setIntProperty(in string nodeName, in string propName, in long value) raises (Error);
    long getIntProperty(in string nodeName, in string propName) raises (Error);

    void callVoidProperty(in string nodeName, in string propName) raises (Error);


    void captureFrame (in WindowID wid, in string imageFilename) raises (Error);

    boolean startCapture (in WindowID wid, in string filename,
      in string extension) raises (Error);

    boolean stopCapture (in WindowID wid) raises (Error);

    boolean setCaptureTransform (in string filename, in Names_t nodeNames)
      raises (Error);

    void captureTransformOnRefresh (in boolean autoCapture) raises (Error);

    void captureTransform () raises (Error);

    boolean writeBlenderScript (in string filename, in Names_t nodeNames) raises (Error);

    boolean writeNodeFile (in string nodeName, in string filename) raises (Error);

    boolean writeWindowFile (in WindowID wid, in string filename) raises (Error);



    boolean attachCameraToNode(in string nodeName, in WindowID wid) raises (Error);

    boolean detachCamera(in WindowID wid) raises (Error);

    Transform getCameraTransform(in WindowID wid) raises (Error);

    boolean setCameraTransform(in WindowID wid, in Transform configuration) raises (Error);

    // register a Node callback
    boolean registerNodeCallback (in NodeCallback cb) raises (Error);

  };
};
};